Membuat Slide Ninja Fruit

Jarang Posting


Hi guys,.Sudah lama ini tidak posting tutorial di blog karena masih ada kesibukan dengan pesanan desain dan revisi game yang baru saja saya terima. Jadi apa boleh buat posting blognya dikurangi.


Ninja Fruit


Ninja fruit?
Pastinya teman-teman pecinta game mobile sudah mendengar atau bahkan memainkan game Ninja Fruit. Game ini cukup menarik, dimana pemain diharuskan memotong buah-buahan yang dilempar secara acak. Poin atau skor akan Anda dapatkan ketika berhasil memotong buah-buah tersebut. Tampilan game Ninja Fruit dapat Anda lihat dibawah ini :

Tampilan Game Ninja Fruit di playstore
Tampilan Game Ninja Fruit di playstore

Membuat Slide

Seperti apakah Slide yang akan kita buat ?
Slide yang akan kita buat adalah seperti tebasan pedang. Dapat Anda lihat seperti pada gambar diatas. Tebasan tersebut akan menebas atau memotong buah menjadi dua bagian. 

Tampilan slide :

Slide Ninja Fruit - game flash
Slide Ninja Fruit - game flash
Yeps, kita hanya membuat bagian slidenya saja berupa garis lurus berwarna hijau yang akan menebas buah-buah. Untuk membuat Slide Ninja Fruit seperti pada gambar diatas menggunakan perangkat lunak (software) Adobe Flash cs 6, dengan bahasa pemrograman Actionscript 3.0.

Frame


Untuk membuat tebasan seperti pada gambar diatas tidak memerlukan banyak frame dan layer, hanya memerlukan satu frame dan satu layer.

layer dan frame yang diperlukan
layer dan frame yang diperlukan
Pada frame satu layer satu, tekan F9 untuk menampilkan Action-Frame :
Penulisan scriptnya bisa Anda ikuti seperti dibawah ini :


import flash.display.*;
import flash.events.Event;
import flash.filters.DropShadowFilter;
import flash.filters.GlowFilter;
import flash.geom.*;
import flash.events.MouseEvent;
     
//definisikan untuk panjang garis yg diinginkan di sini gan
var N:int = 10;
//di dalam kode ini ada sebuah class yang bertipe Vector<> dan bukan bertipe Array
//namun maksudnya sama aja gan, cuman menggunakan vektor lebih enak
var dotarr:Vector.<Point>  = new Vector.<Point> (N,true);
var canvas:Shape = new Shape();

for (var i:int = 0; i < N; i++) {
    dotarr[i] = new Point(mouseX,mouseY);
}
this.addChild(canvas);
//warna glow pertama #ffffff (tidak kelihatan karena sama dgn warna garis)
var glow0:GlowFilter = new GlowFilter(0xffffff,1,16,16,1,1,true,false);
//warna glow dari garis #3BCC16
var glow1:GlowFilter = new GlowFilter(0x3BCC16,1,6,6,1,1,false,false);
var dropShadow0:DropShadowFilter = new DropShadowFilter(0,90,0x39B310,1,24,24,5,3,false,false,false);
canvas.filters = [glow0,glow1,dropShadow0];

//memberikan event enter frame
this.addEventListener(Event.ENTER_FRAME, onEventEnterFrame);
     
//memberikan variabel apakah di klik atau tidak
var isClick:Boolean = false;
     
this.stage.addEventListener(MouseEvent.MOUSE_DOWN, function(e:MouseEvent){
    isClick = true;
        //pada permulaan awal klik, semua nilai dalam variabel dotarr berisi nilai yg sama
        for (var i:int = 0; i < N; i++) {
        dotarr[i] = new Point(mouseX,mouseY);
       }
});
this.stage.addEventListener(MouseEvent.MOUSE_UP, function(e:MouseEvent){
        //saat klik diangkat, mengubah nilai variabel isClick
        isClick = false;
    });
     
    function onEventEnterFrame(e:Event):void {
        if(isClick){
            //jika diklik (dan mouse digerakkan), posisi mouse akan dimasukkan ke dalam array dotarr
            dotarr[N - 1].x = mouseX;
            dotarr[N - 1].y = mouseY;
        }
        var _g:Graphics = canvas.graphics;
        _g.clear();
        var _prevPoint:Point = dotarr[0];
        for (var i:int = 1; i < N; ++i) {
            var _prev:Point = dotarr[i - 1];
            var _current:Point = dotarr[i];
        //mengubah warna garis di sini variabel i merupakan ketebalan (dimulai dari yg
            //paling tipis)
            _g.lineStyle(i, 0xffffff, 1, true, "none", "round", "round");
            var _point:Point = new Point(
             _prev.x + (_current.x - _prev.x) / 2,
             _prev.y + (_current.y - _prev.y) / 2);
            _g.moveTo(_prevPoint.x,_prevPoint.y);
            //ini nih yang bisa bikin melengkung
            _g.curveTo(_prev.x,_prev.y,_point.x,_point.y);
     
            _prevPoint = _point;
            _prev.x = _current.x;
            _prev.y = _current.y;
        }
    }

Ketika ingin melihat hasilnya tekan Ctrl+Enter.


Selain di Komputer, game bisa Anda kembangkan ke Android.
Nah, bagi yang ingin mendownload/mengunduh filenya bisa langsung download disini.

Flash || Adobe Flash cs || Actionscript || Ilmu Flash || Tutorial

Membuat Slide Ninja Fruit Membuat Slide Ninja Fruit Reviewed by Ardy S on February 12, 2016 Rating: 5

1 comment:

Powered by Blogger.